home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tech Arsenal 1
/
Tech Arsenal (Arsenal Computer).ISO
/
tek-20
/
catm100.zip
/
CATII.DO
< prev
next >
Wrap
Text File
|
1991-09-08
|
4KB
|
119 lines
10 '==============================
20 'CAT CONTROL FOR YAESU FT-757GX MARK II
30 ' BY Kjell W. Strom, SM6CPI
40 '
50 ' November 5,1984
60 '==============================
70 DEFINT F,H:H=16
71 'MODIFIED FOR FT-757GX MARK II BY
72 'DICK ROUX N1AED 2/28/89
80 GOSUB 920
90 OPEN "COM:78N2E" FOR OUTPUT AS #1
100 T$=""
110 FOR I=0 TO 9
120 FOR J=0 TO 9
130 T$=T$+CHR$(I*H+J)
140 NEXT:NEXT
150 CLS
160 PRINT" [1] Split [2] MR/VFO"
170 PRINT" [3] V=>M [4] Dial Lock"
180 PRINT" [5] VFO A/B [6] M=>V"
190 PRINT" [7] 500 Khz Up [8] 500 Khz Down"
200 PRINT" [9] Clarifier [10] Frequency"
210 PRINT"[11] V=>/<=M [12] Mode"
220 PRINT"[13] H/G Sel [14] Quit"
230 INPUT" What is your Choice";C
240 IF C<1 OR C>14 THEN 230
250 M$=CHR$(C)
260 IF C=10 THEN 390
270 IF C=14 THEN 880
280 IF C=12 THEN 1090
290 IF C=1 AND CA=1 THEN CA=0:CM=CA ELSE IF C=1 AND CA=0 THEN CA=1:CM=CA
300 IF C=2 AND CB=1 THEN CB=0:CM=CB ELSE IF C=2 AND CB=0 THEN CB=1:CM=CB
310 IF C=3 AND CC=1 THEN CC=0:CM=CD ELSE IF C=3 AND CC=0 THEN CC=1:CM=CC
320 IF C=4 AND CD=1 THEN CD=0:CM=CD ELSE IF C=4 AND CD=0 THEN CD=1:CM=CD
330 IF C=5 AND CE=1 THEN CE=0:CM=CE ELSE IF C=5 AND CE=0 THEN CE=1:CM=CE
340 IF C=6 AND CF=1 THEN CF=0:CM=CF ELSE IF C=6 AND CF=0 THEN CF=1:CM=CF
350 IF C=13 AND CG=1 THEN CG=0:CM=CG ELSE IF C=13 AND CG=0 THEN CG=1:CM=CG
360 IF C=9 AND CI=1 THEN CI=0:CM=CI ELSE IF C=9 AND CI=0 THEN CI=1:CM=CI
370 PRINT #1, CHR$(0);CHR$(0);CHR$(0);CHR$(CM);M$;
380 GOTO 150
390 ' FREQUENCY CONTROL
400 CLS:PRINT
410 INPUT" Frequency Mhz";A
420 IF A<.5 OR A>29.99999 THEN 400
430 GOSUB 690
440 CLS:PRINT A," MHZ"
450 PRINT" New Frequency [F] Other [O]"
460 PRINT" Fine Tuning:"
470 PRINT"[A] 100 <<-<Khz>+>> 100[']"
480 'PRINT
490 PRINT"10 5 1 .1 .01 .01 .1 1 5 10"
500 PRINT"[Z] [X] [C] [V] [B] [N] [M] [,] [.] [/]";
510 C$=INKEY$:IF C$="" THEN 510
520 IF C$="B" OR C$="b" THEN A=A-.00001:GOTO 660
530 IF C$="N" OR C$="n" THEN A=A+.00001:GOTO 660
540 IF C$="V" OR C$="v" THEN A=A-.0001:GOTO 660
550 IF C$="M" OR C$="m" THEN A=A+.0001:GOTO 660
560 IF C$="C" OR C$="c" THEN A=A-.001:GOTO 660
570 IF C$="," THEN A=A+.001:GOTO 660
580 IF C$="X" OR C$="x" THEN A=A-.005:GOTO 660
590 IF C$="." THEN A=A+.005:GOTO 660
600 IF C$="Z" OR C$="z" THEN A=A-.01:GOTO 660
610 IF C$="/" THEN A=A+.01:GOTO 660
620 IF C$="A" OR C$="A" THEN A= A-.1:GOTO 660
630 IF C$="'" THEN A=A+.1:GOTO 660
640 IF C$="F" OR C$="f" THEN 400
650 IF C$="O" OR C$="o" THEN 150
660 IF A <.5 OR A> 29.99999 THEN 440
670 GOSUB 690
680 GOTO 440
690 'HEX/DEC & OUTPUT
700 A$=MID$(STR$(A),2)
710 IF A=INT(A) THEN A$=A$+"."
720 A$="000"+A$+"00000"
730 FOR I=1 TO LEN(A$)
740 DP$=MID$(A$,I,1)
750 IF DP$="." THEN DP=I:GOTO 770
760 NEXT
770 A$=MID$(A$,DP-3,3)+MID$(A$,DP+1,5)
780 F1=VAL(MID$(A$,1,2))
790 F2=VAL(MID$(A$,3,2))
800 F3=VAL(MID$(A$,5,2))
810 F4=VAL(MID$(A$,7,2))
820 G1$=MID$(T$,F1+1,1)
830 G2$=MID$(T$,F2+1,1)
840 G3$=MID$(T$,F3+1,1)
850 G4$=MID$(T$,F4+1,1)
860 PRINT#1,G4$;G3$;G2$;G1$;M$;
870 RETURN
880 INPUT" Are you sure";C$
890 IF C$="Y" OR C$="y" THEN CLOSE1:MENU
900 GOTO 150
910 END
920 'TITLE SCREEN
930 H1$=" C A T p r o g r a m f o r"
940 H2$=" Y A E S U F T - 7 5 7 G X M K I I"
950 H3$=" By Kjell W. Strom SM6CPI"
960 CLS:PRINT:PRINT
970 FOR I=1 TO LEN(H1$)
980 PRINT MID$(H1$,I,1);
990 NEXT
1000 PRINT:PRINT
1010 FOR I= 1 TO LEN(H2$)
1020 PRINT MID$(H2$,I,1);
1030 NEXT
1040 PRINT:PRINT:PRINT
1050 FOR I=1 TO LEN(H3$)
1060 PRINT MID$(H3$,I,1);
1070 NEXT
1080 RETURN
1090 CLS
1100 PRINT
1110 PRINT"[0] LSB [1] USB"
1120 PRINT"[2] CWW [3] CWN"
1130 PRINT"[4] AM [5] FM"
1140 PRINT
1150 INPUT "SELECTION";CM
1160 GOTO 370